Minecraft【作るゲーム】チキンハント。No.2

2020-02-032024-08-13

Java版1.21、統合版はv1.21.2で動作確認。

ニワトリをランダムに召喚し弓矢で倒す、射撃ゲームを作ります。

チキンハントv1.20。

旧式の乱数装置を止め、コマンド「spreadplayers」を使った立体的な乱数装置に変更しました。射撃難易度は上がりましたが、より実践的な弓の練習が出来ると思います。装置はコマンドの数も減り作りやすくなりました。中級者向けとなります。タッチ操作やコントローラーで遊ぶのは難しいので、キーボードとマウス操作推奨。

※記事内容を大幅に変更しました。うまく表示されない場合は、ブラウザのキャッシュをクリアしてください。

◻︎装置の特徴
・回転式、アマスタイマー。
・「spreadplayers」を使った乱数装置。
・ホッパー式のクロック回路。
・ひとつの「防具立て」で、乱数とタイマーを兼用。

更新履歴
2024-6-23／乱数装置を変更して、コマンドも簡略化しました。
2023-5-27／統合版の「test」を廃止して「execute if score」に変更しました。
2023-1-17／Java版1.19以降、統合版のv1.19.50以降に対応。

完成動画。v1.20

旧式／ v1.0はこちら。

1.作成準備
・ログの非表示。
2.コマンドブロックの設置
3.チキンハント装置全体図
・ニワトリの検知。・防具立ての設置。・開始スイッチ。
4.ゲーム回路
・スコアボードの作成。・タイマー装置。・ニワトリ製造機。・クリア報酬。・報酬チェストの中身。
5.仕上げ
・会場作り。
6.遊び方
・操作方法。
7.ワールドデータとスキン
・完成データのダウンロード。・チキンハントスキン。

※「as」や「minecraft:」などのコマンドは簡略化しています。一部のコマンド、マルチプレイやサーバーでは必要な場合があります。

作成準備

ログの非表示。

◻︎ログの非表示と各種ブロックを入手。

/gamerule commandBlockOutput false
/give @s command_block
/give @s structure_block

コマンドブロックの設置

コマンドブロックは画像に合わせて配置。「ブロック種類」「レッドストーン」を変更します。変更がある場合は、個別に解説していきます。

◎配置したコマンドブロックの状態／すべて無条件。

コマンドブロックの色	ブロックの種類	レッドストーン
黄色	インパルス	動力が必要
青色	チェーン	常時実行
紫色	リピート	常時実行

チキンハント装置全体図

フラットワールドを作成したら、座標（0 -60 0）へ移動して開花したツツジの葉を設置。装置は開始点座標（0 -60 0）を基準に、南が正面がになるよう設置にしています。座標を合わせてブロックを設置していくと、コマンドはコピー＆ペーストで作れます。

開始点は座標（0 -60 0）。「あ」は座標（2 -60 12）。「A」は座標（8 -60 18）。①は開始スイッチ（10 -60 25）。「B」は座標（10 -60 26）。※ストラクチャーブロックは目安。

❶プレイエリア　❷ニワトリ散布エリア　❸ゲーム回路

チキンハント装置を3つのエリアに分けて作ります。❷散布エリアでは、ニワトリが落ちる範囲が分かるように「あ」の座標から、内側に13×13ブロックの空きスペースを作り、外周をフェンスゲートで囲みます。

◻︎南向きを確認するには
ストラクチャーブロックを設置して、境界線の青い線が伸びる方が南。※赤い線は東へ。

ニワトリの検知。

❷散布エリア内で、地面に降りたニワトリを検知するため、引数を使用します。高さ（dy＝）は0ブロック。xとy軸の座標を確認。

❷散布エリア
「あ」の座標を含め、13×13ブロックの範囲（引数）。
@e[x=2,y=-60,z=12,dx=12,dy=0,dz=12]

防具立ての設置。

❷散布エリア「A」の座標は中心。感圧版と防具立てを設置。

【Java版】

/summon armor_stand 8 -60 18 {CustomName:"\"チキン\""}

【統合版】

/summon armor_stand チキン 8 -60 18

「チキン」と名前を付けた防具立てを設置。※タグを使ってもOKです。

◎防具立てを透明にする
【Java版】コマンドに「,Invisible:1b」を追加。
【統合版】エフェクトを使います。コマンドブロッック（リピート:常時実行）
effect @e[name=チキン] invisibility 1 0 true

開始スイッチ。

❶プレイエリアの「B」はトラップチェスト。開けた時①のコマンドを実行します。

トラップチェストの向きが正面になるように設置。開始スイッチはボタンや感圧版でもOKです。

【Java版／統合版】共通

①scoreboard players set 残り:秒 count 60

①スコアボード「count」の残り:秒に60をセット。

ゲーム回路

スコアボードの作成。

スコアボード「count」を作り、サイドバーに表示しておきます。さらにニワトリがアイテムを落とさないないように、ゲームルールも変更しておきます。

【Java版／統合版】共通

scoreboard objectives add count dummy "スコア"
scoreboard objectives setdisplay sidebar count
------
/gamerule doMobLoot false

◎統合版はダブルクォーテーションマーク「"」無し。
/scoreboard objectives add time dummy スコア

タイマー装置。

防具立てを回転して、1秒のクロック回路を作成。※1周で約1秒。

①は座標（13 -60 6）。②にはレッドストーントーチを設置。④は動力が必要。⑤は条件付き。

【Java版】

①execute if score 残り:秒 count matches 1..60
------
②execute at @e[name="チキン"] run tp @e[name="チキン"] ~ ~ ~ 0 ~
③scoreboard players set 逃した数 count 0
------
④execute at @e[name="チキン"] run tp @e[name="チキン"] ~ ~ ~ ~18 ~
⑤execute if entity @e[name="チキン",y_rotation=0] run scoreboard players remove 残り:秒 count 1
------
⑥kill @e[type=arrow]

【統合版】②④⑤以外はJava版と同じ。

②execute at @e[name=チキン] run tp @e[name=チキン] ~ ~ ~ 0 ~
------
④execute at @e[name=チキン] run tp @e[name=チキン] ~ ~ ~ ~18 ~
⑤execute if entity @e[name=チキン,rym=0,ry=0] run scoreboard players remove 残り:秒 count 1

①「count」の残り:秒が1から60の時、信号を出す。
------
②防具立て「チキン」の向きを０度（南向き）に回転。
③「count」の逃した数を0にセット。
------
④防具立て「チキン」を1ティックで18度回転。
⑤防具立て「チキン」の向きが０度（南向き）になった時、「count」の残り:秒を1引く。
------
⑥落ちている矢を削除。

ニワトリ製造機。

ホッパー式クロック回路で、ニワトリを散布。残り時間に合わせて、散布時間を早くします。また、地面に落ちたニワトリの数を数えます。

⑧⑨は条件付き。「い」「う」にはレッドストーントーチを設置。矢印はホッパーの向き。

【Java版】

①execute if score 残り:秒 count matches 21..60
------
②execute if score 残り:秒 count matches 1..20
------
③title @a title "RUSH!RUSH!"
④playsound block.bell.use player @a 8 -60 18 1 1
------
⑤spreadplayers 8 18 0 6 false @e[name="チキン"]
⑥execute at @e[name="チキン"] run summon chicken ~ ~10 ~
------
⑦execute if entity @e[type=chicken,x=2,y=-60,z=12,dx=12,dy=0,dz=12]
⑧scoreboard players add 逃した数 count 1
⑨kill @e[type=chicken,x=2,y=-60,z=12,dx=12,dy=0,dz=12]

【統合版】①以外はJava版と同じ。

③title @a title RUSH!RUSH!
④playsound block.bell.hit @a 8 -60 18 1 1
------
⑤spreadplayers 8 18 0 6 @e[name=チキン]
⑥execute at @e[name=チキン] run summon chicken ~ ~10 ~

【「A」の座標、❷散布エリアは装置全体図参照】
①「count」の残り:秒が21から60の時、信号を出す。
②「count」の残り:秒が1から20の時、信号を出す。
------
③タイトルに「RUSH!RUSH!」を表示。
④「A」の座標で鐘の音を鳴らす。※統合版は聞こえる範囲が狭いので注意。
------
⑤「A」の座標を中心に、6ブロックの範囲で防具立て「チキン」を散布。
⑥防具立て「チキン」の10ブロック上に、ニワトリを召喚。
------
⑦❷散布エリア（地面）にニワトリがいる時、信号を出す。
⑧「count」の逃した数に1を足す。
⑨❷散布エリア（地面）にいるニワトリをキル。

クリア報酬。

逃したニワトリの数に合わせて、報酬とメッセージを変更します。

②③⑤⑥⑧⑨は条件付き。矢印はチェストの向き。「え」は座標（13 -60 0）。「お」は座標（11 -60 0）。「か」は座標（9 -60 0）。

【Java版】

①execute if score 逃した数 count matches 17..
②title @a title "修行が足りぬ！"
③clone 13 -60 0 13 -60 0 10 -60 26
------
④execute if score 逃した数 count matches 11..16
⑤title @a title "上級者！"
⑥clone 11 -60 0 11 -60 0 10 -60 26
------
⑦execute if score 逃した数 count matches 0..10
⑧title @a title "達人！"
⑨clone 9 -60 0 9 -60 0 10 -60 26

【統合版】②⑤⑧以外はJava版と同じ。

②title @a title 修行が足りぬ！
⑤title @a title 上級者
⑧title @a title 達人！

【❶プレイエリアは、装置全体図参照】
①「count」の逃した数が17以上の時、信号を出す。
②タイトルに「修行が足りぬ！」を表示。
③「え」のチェストを、❶プレイエリア「B」にクローン。
------
④⑤⑥⑦⑧⑨も手順は同じなので、説明は割愛します。

報酬チェストの中身。

「え」「お」「か」のトラップチェストにはエンチャントで強化した武器と矢を多めに入れておきます。アイテムを手に持った状態で、エンチャントコマンドを実行します。

例）「え」弓と矢。「お」弓と矢、クロスボウ。「か」弓と矢、トライデント。

◻︎弓　射撃ダメージ（パワー）
/enchant @s power 5
◻︎クロスボウ　高速充填・拡散（クイックチャージ・マルチショット）
/enchant @s quick_charge 3
/enchant @s multishot
◻︎トライデント　忠誠（忠誠心）　投げたトライデントが手元に戻る。
/enchant @s loyalty

仕上げ

会場作り。

フェンスゲートに飾りを付けたり、ショップ風の壁を作り会場を仕上げます。

◎作成ポイント

フェンス内にはニワトリが落ちてくるので、ブロックはあまり置かない方が良い。コマンドブロックが気になる場合は、地面下や建物内に隠します。マルチプレイで遊ぶには、武器を増やしたり、難易度を調整してください。ゲームモードをアドベンチャーモードにしたら完成です。※サバイバルやクリエイティブモードでは、弓矢で防具立てが壊れてしまうので注意。